サンプル

利点

  • トラクションが均等にかけられる。
    だから浮いた車輪が空転して接地した瞬間に暴走ということがない。

欠点

  • タイヤを軸ごとまわすという特性により、Engineをmax=50000にしても最高速度は200kmしかでない。

せまいサーキットかクロカン用と割り切ったほうがいい。

Val

	SPG(default=0.0,max=0.6,step=1)
	DMP(default=0.0,max=0.6,step=1)
	NA(min=-100000)
	SA(min=-100000)

Body

	S:Trim(angle=90){
	//駆動ホイール
	 S:WHeel(angle=180,power=-Engine,brake=Hbrake){
	//軸1
	  N:Frame(angle=120,option=1){
	   N:Frame(angle=150,option=1,name=N){
	//差動装置
	    N:Trimf(angle=NA,option=1,spring=SPG,damper=DMP,angle=0){
	     N:Frame(angle=-30,option=1){}//バランス取り
	     N:Frame(angle=30,option=1){
	//接地ホイール
	      N:WHeel(angle=-120,brake=1000,option=2,effect=5){}
	     }
	    }
	   }
	  }
	//軸2
	  S:Frame(angle=-120,option=1){
	   S:Frame(angle=-150,option=1,name=S){
	//差動装置
	    S:Trimf(angle=-SA,option=1,spring=SPG,damper=DMP,angle=0){
	     S:Frame(angle=30,option=1){}//バランス取り
	     S:Frame(angle=-30,option=1){
	//接地ホイール
	      S:WHeel(angle=120,brake=1000,option=2,effect=5){}
	     }
	    }
	   }
	  }
	 }
	}

Script

	if Engine=0 & HBrake=0 {NA=_todeg(_RZ(N,N+1))
			SA=_todeg(_RZ(S,S+1))}
	//EngineとHBrakeが0だったら現在の角度を記録する。
	//減速側にHBrakeを使うのは普通のブレーキでもサイドブレーキでも使用されるため。
	spg=0
	dmp=0
	if Engine<>0 | Hbrake>0 {
		spg=0.6
		dmp=0.6
	}
	//EngineかHbrakeが0以外だったらspgとdmpを0.6にして差動装置をロックする。


セッティングについて

  • 設定例は加減速させるときに車軸を固定する2wayデフ。
  • 何も入力がないときは左右の車軸の結合をはずして曲がりやすくして、
    アクセルやブレーキを入れたときには固めて力を路面に伝えやすくする。
    これによってコーナリングを妨げないようになっている。
  • このサスはトリムの設定がデフの設定を変化させる。
    たとえば、SPGとDMPを
    0.6から0.02などに下げれば加減速時も若干曲がりやすくなるはず。

解説

  1. まずボディ中央から後ろに90度捻って駆動用Wheelを取り付ける。 これがデフの駆動力伝達の部分の役割をする。
  2. WheelからWheelの回転中心で直角となるようにフレームを伸ばして、Trimを取り付ける。 これがデフの差動部分となる。
  3. Trimから駆動用Wheelのふちと同じ高さになるようにFrameを持ち上げ、接地用Wheelをつける。〜 これにより、駆動用Wheelと接地用Wheelが同じ中心で回転するようになる。
  4. Trimにspringとdamperを与え、自由に回るようにする。
    そのままだとほとんどノンスリデフと変わらないので、Scriptを用意する。
  5. Scriptはアクセルオフの時にTrimの現在の角度を取得し、アクセルオンの時に固定位置をリセットする役割をする。
    また、spgとdmpを変更することによってアクセルオンやブレーキの時に軸をロックさせる。
  6. サスペンションが必要だったら、1.の捻る直前にChipを入れるか、捻った後のWheelの前にRudderを用意し必要な硬さに設定する。
    最初の捻りTrimにSpringとDamperを設定するのも有効。
rc_rigid.png

それぞれの軸はWheelから120,150°の順で出ていて、Wheelの中心を通る。
二回曲がった後にTrimが待ち構えていて、spgとdmpでロック・アンロックを制御されている。
このあとTrimから30°で曲がり、Wheelに120°で接続する。


参考
差動装置 - Wikipedia

添付ファイル: filerc_rigid.png 401件 [詳細] fileロッククローラ.rcd 1243件 [詳細]